<Serializable>
Public Class CustomFilter
    Inherits FarPoint.Win.Spread.BaseFilterItem
    Private sv As FarPoint.Win.Spread.SheetView = Nothing
    Public Sub New()
    End Sub
    Public Overrides ReadOnly Property DisplayName() As String
        'フィルタに表示する文字列
        Get
            Return "1000以上5000以下"
        End Get
    End Property
    Public Overrides WriteOnly Property SheetView() As FarPoint.Win.Spread.SheetView
        Set
            sv = Value
        End Set
    End Property
    Private Function IsNumeric(ovalue As Object) As Boolean
        Dim _isNumber As New System.Text.RegularExpressions.Regex("^\-?\d+\.?\d*$")
        Dim m As System.Text.RegularExpressions.Match = _isNumber.Match(Convert.ToString(ovalue))
        Return m.Success
    End Function
    Public Function IsFilteredIn(ovalue As Object) As Boolean
        Dim ret As Boolean = False
        If IsNumeric(ovalue) Then
            If [Double].Parse(Convert.ToString(ovalue)) >= 1000 AndAlso [Double].Parse(Convert.ToString(ovalue)) <= 5000 Then
                ret = True
            End If
        End If
        Return ret
    End Function
    Public Overrides Function ShowInDropDown(columnIndex As Integer, filteredInRowList As Integer()) As Boolean
        ' filteredInRowList引数はフィルターイン行リスト
        ' 条件に合うデータが存在する時のみ項目リストに表示
        If filteredInRowList Is Nothing Then
            For i As Integer = 0 To sv.RowCount - 1
                Dim value As Object = sv.GetValue(i, columnIndex)
                If value IsNot Nothing Then
                    If IsFilteredIn(value) Then
                        Return True
                    End If
                End If
            Next
        Else
            ' 現在の行リストが条件に合致するか確認
            For i As Integer = 0 To filteredInRowList.Length - 1
                Dim row As Integer = filteredInRowList(i)
                Dim value As Object = sv.GetValue(row, columnIndex)
                If value IsNot Nothing Then
                    If IsFilteredIn(value) Then
                        Return True
                    End If
                End If
            Next
        End If
        Return False
    End Function
    Public Overrides Function Filter(columnIndex As Integer) As Integer()
        Dim ar As New System.Collections.ArrayList()
        Dim val As Object
        For i As Integer = 0 To sv.RowCount - 1
            val = sv.GetValue(i, columnIndex)
            If IsFilteredIn(val) Then
                ar.Add(i)
                '条件に合致する行番号をリストに追加
            End If
        Next
        Return DirectCast(ar.ToArray(GetType(Int32)), Int32())
    End Function
    Public Overrides Function Serialize(w As System.Xml.XmlTextWriter) As Boolean
        w.WriteStartElement("CustomFilter")
        MyBase.Serialize(w)
        w.WriteEndElement()
        Return True
    End Function
    Public Overrides Function Deserialize(r As System.Xml.XmlNodeReader) As Boolean
        If r.NodeType = System.Xml.XmlNodeType.Element Then
            If r.Name.Equals("CustomFilter") Then
                MyBase.Deserialize(r)
            End If
        End If
        Return True
    End Function
End Class
'以下をコードビハインドに記述します
' 2列目にフィルタの列定義を作成
Dim fcd1 As New FarPoint.Win.Spread.FilterColumnDefinition(1,
    FarPoint.Win.Spread.FilterListBehavior.Custom Or FarPoint.Win.Spread.FilterListBehavior.Default)
' カスタムフィルタを列定義に追加
fcd1.Filters.Add(New CustomFilter() With {.SheetView = FpSpread1.Sheets(0)})
' 非表示フィルタの作成
Dim hideRowFilter As New FarPoint.Win.Spread.HideRowFilter(FpSpread1.Sheets(0))
hideRowFilter.AddColumn(fcd1)
FpSpread1.Sheets(0).RowFilter = hideRowFilter
' テストデータを設定
FpSpread1.Sheets(0).SetValue(0, 1, 999)
FpSpread1.Sheets(0).SetValue(1, 1, 1000)
FpSpread1.Sheets(0).SetValue(2, 1, 5000)