Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim test As New CompanyWatermark(0, 0, 550, 200)
    FpSpread1_Sheet1.AddShape(test)
End Sub

Imports System.Runtime.Serialization
Imports System.Xml
Imports FarPoint.Win
Imports FarPoint.Win.Spread.DrawingSpace
<Serializable()> Public Class CompanyWatermark
    Inherits RectangleShape
    Implements ISerializable
    Private mCompanyColor As Color = Color.Green
    Private mCompanyLogo As Image = My.Resources.SampleLogo
    Private mCompanyName As String = "[Company Name]"
    Private mCompanyText As String = "[Company Text]"
    Friend Sub New()
    End Sub
    ' required for ISerializeSupport
    Public Sub New(left As Integer, top As Integer, width As Integer, height As Integer)
        MyBase.New()
        CanRotate = False
        SetBounds(left, top, width, height)
        UpdateChildren()
    End Sub
    Public Sub New(info As SerializationInfo, context As StreamingContext)
        MyBase.New(info, context)
        mCompanyColor = DirectCast(info.GetValue("cc", GetType(Color)), Color)
        mCompanyLogo = DirectCast(info.GetValue("cl", GetType(Image)), Image)
        mCompanyName = info.GetString("cn")
        mCompanyText = info.GetString("ct")
        UpdateChildren()
    End Sub
    Public Overrides Sub GetObjectData(info As SerializationInfo, context As StreamingContext)
        MyBase.GetObjectData(info, context)
        info.AddValue("cc", mCompanyColor)
        info.AddValue("cl", mCompanyLogo)
        info.AddValue("cn", mCompanyName)
        info.AddValue("ct", mCompanyText)
    End Sub
    Public Property CompanyColor() As Color
        Get
            Return mCompanyColor
        End Get
        Set
            mCompanyColor = Value
            UpdateChildren()
        End Set
    End Property
    Public Property CompanyLogo() As Image
        Get
            Return mCompanyLogo
        End Get
        Set
            mCompanyLogo = Value
            UpdateChildren()
        End Set
    End Property
    Public Property CompanyName() As String
        Get
            Return mCompanyName
        End Get
        Set
            mCompanyName = Value
            UpdateChildren()
        End Set
    End Property
    Public Property CompanyText() As String
        Get
            Return mCompanyText
        End Get
        Set
            mCompanyText = Value
            UpdateChildren()
        End Set
    End Property
    Public Overrides Sub Rotate(angle As Single)
        MyBase.Rotate(angle)
        For Each shape As PSShape In ContainedObjects
            shape.RotationAngle = angle
        Next
    End Sub
    Public Overrides Function Deserialize(r As XmlNodeReader) As Boolean
        Dim inCompanyColor As Boolean = False
        Dim inCompanyLogo As Boolean = False
        Dim doc As New XmlDocument()
        Dim node As XmlNode
        Dim r2 As XmlNodeReader
        Dim r3 As XmlNodeReader
        Dim r4 As XmlNodeReader
        r.MoveToElement()
        node = doc.ReadNode(r)
        r2 = New XmlNodeReader(node)
        r3 = New XmlNodeReader(node)
        r4 = New XmlNodeReader(node)
        PSObject.Deserialize(Me, r2)
        PSShape.Deserialize(Me, r3)
        While r4.Read()
            Select Case r.NodeType
                Case XmlNodeType.Element
                    If r.Name.Equals("CompanyColor") Then
                        inCompanyColor = True
                    ElseIf r.Name.Equals("CompanyLogo") Then
                        inCompanyLogo = True
                    ElseIf r.Name.Equals("CompanyName") Then
                        mCompanyName = Serializer.DeserializeString(r)
                    ElseIf r.Name.Equals("CompanyText") Then
                        mCompanyText = Serializer.DeserializeString(r)
                    End If
                    Exit Select
                Case XmlNodeType.Text
                    If inCompanyColor Then
                        mCompanyColor = Serializer.DeserializeColorValue(r.Value)
                    ElseIf inCompanyLogo Then
                        mCompanyLogo = Serializer.DeserializeImage(r.Value)
                    End If
                    Exit Select
                Case XmlNodeType.EndElement
                    If inCompanyColor AndAlso r.Name.Equals("CompanyColor") Then
                        inCompanyColor = False
                    ElseIf inCompanyLogo AndAlso r.Name.Equals("CompanyLogo") Then
                        inCompanyLogo = False
                    End If
                    Exit Select
            End Select
        End While
        Return True
    End Function
    Public Overrides Function Serialize(w As XmlTextWriter) As Boolean
        w.WriteStartElement("PSShape")
        w.WriteAttributeString("class", Me.[GetType]().FullName)
        w.WriteAttributeString("assembly", Me.[GetType]().Assembly.FullName)
        PSShape.Serialize(Me, w)
        Serializer.SerializeColor(mCompanyColor, "CompanyColor", w)
        Serializer.SerializeImage(mCompanyLogo, "CompanyLogo", w)
        Serializer.SerializeString(mCompanyName, "CompanyName", w)
        Serializer.SerializeString(mCompanyText, "CompanyText", w)
        w.WriteEndElement()
        ' object
        Return True
    End Function
    Private Sub UpdateChildren()
        ShapeOutlineThickness = 0
        If ContainedObjects.Count = 0 Then
            ' create the child shapes
            ' gradient effect for company color
            BackColor = Color.Transparent
            Gradient.Sections = New GradientSection() {New GradientSection(mCompanyColor, 255, 200), New GradientSection(Color.White, 255, 255)}
            Gradient.Style = GradientStyle.LinearTopDown
            ' company logo is aligned to left and uses image width and height to align company text below
            Dim logo As New RectangleShape()
            logo.BackColor = Color.Transparent
            logo.ShapeOutlineThickness = 0
            logo.SetBounds(0, 0, mCompanyLogo.Width, mCompanyLogo.Height)
            logo.Picture = mCompanyLogo
            logo.PictureTransparencyColor = Color.White
            ContainedObjects.Add(logo)
            Dim name As New TextShape()
            name.Text = mCompanyName
            name.ForeColor = Color.Orange
            name.ShapeOutlineColor = Color.Black
            name.ShapeOutlineStyle = System.Drawing.Drawing2D.DashStyle.Solid
            name.ShapeOutlineThickness = 1
            ContainedObjects.Add(name)
            name.SetBounds(logo.Width + 5, (logo.Height - name.Height) / 2, name.Width, name.Height)
            Dim text As New TextShape()
            text.Text = mCompanyText
            text.ForeColor = Color.Red
            text.ShapeOutlineColor = Color.Black
            text.ShapeOutlineStyle = System.Drawing.Drawing2D.DashStyle.Solid
            text.ShapeOutlineThickness = 1
            ContainedObjects.Add(text)
            text.SetBounds(0, logo.Height + 5, text.Width, text.Height)
        Else
            ' update the child shapes
            Dim logo As RectangleShape = DirectCast(ContainedObjects(0), RectangleShape)
            Dim name As TextShape = DirectCast(ContainedObjects(1), TextShape)
            Dim text As TextShape = DirectCast(ContainedObjects(2), TextShape)
            Gradient.Sections = New GradientSection() {New GradientSection(mCompanyColor, 50), New GradientSection(Color.White, 50)}
            logo.Picture = mCompanyLogo
            name.Text = mCompanyName
            text.Text = mCompanyText
        End If
    End Sub
End Class