Imports System.IO
Imports C1.C1Zip

Private m_Zip As C1ZipFile

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
     ' C1ZipFile メンバを作成します。
    m_Zip = New C1ZipFile()
End Sub

Private Sub btnNew_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnNew.Click
     ' ファイルを開くダイアログを表示します。
    Dim fo As SaveFileDialog = New SaveFileDialog()
    fo.FileName = "*.zip"
    If fo.ShowDialog() <> Windows.Forms.DialogResult.OK Then
        Exit Sub
    End If
     ' zip ファイルを開きます。
    Try
        m_Zip.Create(fo.FileName)
    Catch
        MessageBox.Show("Can't create ZIP file, please try again.", "C1Zip")
    End Try
     ' UI を更新します。
    UpdateDisplay()
End Sub

Private Sub btnOpen_Click(sender As Object, e As EventArgs) Handles btnOpen.Click
     ' ファイルを開くダイアログを表示します。
    Dim fo As OpenFileDialog = New OpenFileDialog()
    fo.FileName = "*.zip"
    If fo.ShowDialog() <> Windows.Forms.DialogResult.OK Then Exit Sub
    Try
        m_Zip.Open(fo.FileName)
    Catch
        MessageBox.Show("Invalid ZIP file, please try again.")
    End Try
      ' UI を更新します。
    UpdateDisplay()
End Sub

Private Sub UpdateDisplay()
      ' ListView コントロールを更新して、zip ファイルの内容を表示します。
    With ListView1
          ' 既存の項目を削除します。
        .Items.Clear()
         ' 各エントリを追加します。
        Dim ze As C1ZipEntry
        For Each ze In m_Zip.Entries
              ' 圧縮量を計算します。
            Dim pct As Double = 0
            If ze.SizeUncompressed > 0 Then
                pct = 1 - ze.SizeCompressed / ze.SizeUncompressed
            End If
             ' ListView 項目を構築します。
            Dim items(4) As String
            items(0) = ze.FileName
            items(1) = Format(ze.Date, "MM/dd/yy")
            items(2) = Format(ze.SizeUncompressed, "#,##0")
            items(3) = Format(ze.SizeCompressed, "#,##0")
            items(4) = Format(pct, "00 %")
            Dim lvi As ListViewItem = New ListViewItem(items)
              ' ZipEntry を項目タグに保存します。
            lvi.Tag = ze
              ' 項目を ListView に追加します。
            .Items.Add(lvi)
        Next ze
         ' UI を更新します。
        Dim hasEntries As Boolean = (.Items.Count > 0)
        btnExtract.Enabled = hasEntries
        btnRemove.Enabled = hasEntries
        btnTest.Enabled = hasEntries
    End With
End Sub

Private Sub btnTest_Click(sender As Object, e As EventArgs) Handles btnTest.Click
     ' 各エントリをテストします。
    Dim ze As C1ZipEntry
    For Each ze In m_Zip.Entries
        If Not ze.CheckCRC32() Then
            MessageBox.Show("** Entry " & ze.FileName & " has errors.", "C1Zip", MessageBoxButtons.OK, MessageBoxIcon.Error)
            Exit Sub
        End If
    Next
      ' ここまで到達すれば問題はありません。
    MessageBox.Show("All entries passed CRC check", "C1Zip")
End Sub

Private Sub btnView_Click(sender As Object, e As EventArgs) Handles btnView.Click
      ' 最初に選択されたディレクトリではない項目を取得します。
    Dim ze As C1ZipEntry = Nothing
    Dim lvi As ListViewItem
    For Each lvi In ListView1.SelectedItems
        Dim zeItem As C1ZipEntry = lvi.Tag
        If (zeItem.Attributes And FileAttributes.Directory) = 0 Then
            ze = zeItem
            Exit For
        End If
    Next lvi
      ' 項目を取得したことを確認します。
    If ze Is Nothing Then
        MessageBox.Show("Sorry, no files to show...", "C1Zip")
        Exit Sub
    End If
     ' エントリの内容を文字列に読み取ります。
    Dim entry As Stream = ze.OpenReader()
    Dim sr As StreamReader = New StreamReader(entry)
    Dim entryText As String = sr.ReadToEnd()
    entry.Close()
     ' エントリが MessageBox に対して長すぎないようにします。
    If entryText.Length > 16000 Then
        entryText = entryText.Substring(0, 16000)
    End If
      ' メッセージボックスにエントリを表示します。
    MessageBox.Show(entryText, ze.FileName)
End Sub

Private Sub btnAdd_Click(sender As Object, e As EventArgs) Handles btnAdd.Click
     ' 追加するファイルのリストを取得します。
    Dim fo As OpenFileDialog = New OpenFileDialog()
    fo.Multiselect = True
    fo.FileName = "*.*"
    If fo.ShowDialog <> Windows.Forms.DialogResult.OK Then Exit Sub
     ' リストにファイルを追加します。
    Dim file As String
    For Each file In fo.FileNames()
        m_Zip.Entries.Add(file)
    Next file
      ' 完了。
    UpdateDisplay()
End Sub

Private Sub btnExtract_Click(sender As Object, e As EventArgs) Handles btnExtract.Click
      ' いくつかのエントリを選択していることを確認します。
    Dim cnt As Integer = ListView1.SelectedIndices.Count
    If cnt = 0 Then
        MessageBox.Show("Sorry, no files to extract...", "C1Zip")
        Exit Sub
    End If
     ' ユーザーに確認します。
    Dim dr As DialogResult
    Dim msg As String
    msg = "Please confirm that you want to extract " + cnt.ToString() + " entries."
    dr = MessageBox.Show(msg, "C1Zip", MessageBoxButtons.OKCancel, MessageBoxIcon.Question)
    If dr <> Windows.Forms.DialogResult.OK Then Exit Sub
     ' 選択されたすべてのエントリを抽出します。
    Dim lvi As ListViewItem
    Dim ze As C1ZipEntry
    For Each lvi In ListView1.SelectedItems
        ze = lvi.Tag
        If ze.SizeCompressed > 0 Then
             m_Zip.Entries.Extract(ze.FileName)
        End If
    Next lvi
      ' 完了。
    UpdateDisplay()
End Sub

Private Sub btnRemove_Click(sender As Object, e As EventArgs) Handles btnRemove.Click
      ' いくつかのエントリを選択していることを確認します。
    Dim cnt As Integer = ListView1.SelectedIndices.Count
    If cnt = 0 Then
        MessageBox.Show("Oops, no files to remove...", "C1Zip")
        Exit Sub
    End If
     ' ユーザーに確認します。
    Dim dr As DialogResult
    Dim msg As String
    msg = "Please confirm that you want to delete " + cnt.ToString() + " entries."
    dr = MessageBox.Show(msg, "C1Zip", MessageBoxButtons.OKCancel, MessageBoxIcon.Question)
    If dr <> Windows.Forms.DialogResult.OK Then Exit Sub
      ' 選択されたすべてのエントリを削除します。
    Dim lvi As ListViewItem
    Dim ze As C1ZipEntry
    For Each lvi In ListView1.SelectedItems
        ze = lvi.Tag
        m_Zip.Entries.Remove(ze.FileName)
    Next lvi
      ' 完了。
    UpdateDisplay()
End Sub