' データ連結
GcSpreadGrid1.ItemsSource = New EmployeeCollection()
' 非連結列の設定
GcSpreadGrid1.Columns.Add()
GcSpreadGrid1.Columns(GcSpreadGrid1.ColumnCount - 1).Name = "Comment"
GcSpreadGrid1.Columns("Comment").Header = "備考"
' 書式
Dim g As New GeneralCellType()
g.FormatString = "yyyy年MM月dd日"
gcSpreadGrid1.Columns("HireDate").CellType = g
gcSpreadGrid1.Columns("Birthday").CellType = g
Dim g2 As New GeneralCellType()
g2.TextWrapping = TextWrapping.Wrap
GcSpreadGrid1.Columns("Comment").CellType = g2
' テンプレート定義
Dim t As New LayoutTemplate()
t.ColumnDefinitions.Add(New TemplateColumnDefinition() With {.Width = 90})
t.ColumnDefinitions.Add(New TemplateColumnDefinition() With {.Width = 120})
t.ColumnDefinitions.Add(New TemplateColumnDefinition() With {.Width = 255})
' 行テンプレート（1レコード2行）
t.RowTemplate = New RowTemplate()
t.RowTemplate.RowDefinitions.Add(New TemplateRowDefinition() With {.Height = 20})
t.RowTemplate.RowDefinitions.Add(New TemplateRowDefinition() With {.Height = 20})
' 行テンプレート1行目
t.RowTemplate.Cells.Add(New CellTemplate() With {.RowIndex = 0, .ColumnIndex = 0, .DataColumnName = "ID"})
t.RowTemplate.Cells.Add(New CellTemplate() With {.RowIndex = 0, .ColumnIndex = 1, .DataColumnName = "HireDate"})
t.RowTemplate.Cells.Add(New CellTemplate() With {.RowIndex = 0, .ColumnIndex = 2, .DataColumnName = "Comment", .RowSpan = 2})
' 行テンプレート2行目
t.RowTemplate.Cells.Add(New CellTemplate() With {.RowIndex = 1, .ColumnIndex = 0, .DataColumnName = "Name"})
t.RowTemplate.Cells.Add(New CellTemplate() With {.RowIndex = 1, .ColumnIndex = 1, .DataColumnName = "Birthday"})

GcSpreadGrid1.LayoutTemplate = t
GcSpreadGrid1.LayoutMode = LayoutMode.Template

<CustomValidation(GetType(EmployeeValidator), "IsGrownUp")> _
Public Class Employee
    Implements INotifyPropertyChanged
    Private m_id As String
    Private m_name As String
    Private m_hiredate As DateTime
    Private m_birthday As DateTime

    <Required(ErrorMessage:="IDは必ず入力してください。")>
    Public Property ID() As String
        Get
            Return m_id
        End Get
        Set(value As String)
            m_id = value
            NotifyPropertyChanged("ID")
        End Set
    End Property
    <Display(ShortName:="氏名")> _
    Public Property Name() As String
        Get
            Return m_name
        End Get
        Set(value As String)
            m_name = value
            NotifyPropertyChanged("Name")
        End Set
    End Property
    <Display(ShortName:="入社日")> _
    Public Property HireDate() As DateTime
        Get
            Return m_hiredate
        End Get
        Set(value As DateTime)
            m_hiredate = value
            NotifyPropertyChanged("HireDate")
        End Set
    End Property
    <Display(ShortName:="誕生日")> _
    Public Property Birthday() As DateTime
        Get
            Return m_birthday
        End Get
        Set(value As DateTime)
            m_birthday = value
            NotifyPropertyChanged("Birthday")
        End Set
    End Property
    Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged
    Protected Sub NotifyPropertyChanged(propertyName As String)
        RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName))
    End Sub
End Class
Public Class EmployeeValidator
    Public Shared Function IsGrownUp(employee As Employee) As ValidationResult
        Dim result As ValidationResult = Nothing
        If employee.Birthday.AddYears(20).CompareTo(employee.HireDate) = 1 Then
            result = New ValidationResult("20歳以上の方しか勤務できません。", New String() {"Birthday", "HireDate"})
        End If
        Return result
    End Function
End Class
Public Class EmployeeCollection
    Inherits ObservableCollection(Of Employee)
    Public Sub New()
        Add(New Employee() With {.ID = "U10200115", .Name = "福山 敏道", _
                                 .HireDate = DateTime.Parse("2003/12/1"), .Birthday = DateTime.Parse("1977/9/17")})
    End Sub
End Class